ezAPI ASP (VBS) - Who's Online

ASP (VBScript) Implementation of Who's Online

by phalen180

Code:

sPub = "beta"
sBoardID = "bezboard"
sBoardName = "Help Forums"

Response.Write(ezapiWhosOnline(sPub, sBoardID, sBoardName))

Public Function ezapiWhosOnline(sPub, sBoardID, sBoardName)
	'Initialize return value
	ezapiWhosOnline = ""

'Get ezAPI Data
	Set ezWhosOnline = Server.CreateObject("Msxml2.ServerXMLHTTP.4.0")
	ezWhosOnline.setTimeouts 5000,8000,10000,45000
	ezWhosOnline.Open "GET","http://" & sPub & ".ezboard.com/" & sBoardID & ".ezAPIWhosOnline", False
	ezWhosOnline.Send

'Split ezAPI data
	aWhosOnline = split(ezWhosOnline.responseText, vbCr)

'Destroy unneeded objects
	Set ezWhosOnline = Nothing
	
	'Parse ezAPI data
	For wo = 0 to UBound(aWhosOnline) Step 2
		Select Case aWhosOnline(wo)
			Case "wo_retcode"
				If aWhosOnline(wo + 1) <> "OK" Then
					ezapiWhosOnline = "Unable to retrieve Who's Online Information"
					Exit Function
				End If
				ezapiWhosOnline = ("Who's Online statistics for <a href=""http://" & sPub & ".ezboard.com/" & sBoardID & """>" & sBoardName & "</a><br>") & vbCrLf
			Case "wo_visitors"
				iOnlineUsers = aWhosOnline(wo + 1)
			Case "wo_members"
				iOnlineMembers = aWhosOnline(wo + 1)
			Case "wo_guests"
				iOnlineGuests = aWhosOnline(wo + 1)
			Case "wo_anonymous"
				iOnlineAnon = aWhosOnline(wo + 1)
			Case "wo_ids"
				aOnlineProfiles = split(aWhosOnline(wo + 1), ",")
			Case "wo_names"
				aOnlineNames = split(aWhosOnline(wo + 1), ",")
		End Select
	Next

'Destroy unneeded array
	aWhosOnline = Null

'If there is data, return it
	If iOnlineUsers > 0 Then
		ezapiWhosOnline = ezapiWhosOnline & (iOnlineUsers & " visitors in the last 15 minutes: ")
		If iOnlineMembers > 0 Then ezapiWhosOnline = ezapiWhosOnline & (iOnlineMembers & " Members ")
		If iOnlineGuests > 0 Then ezapiWhosOnline = ezapiWhosOnline & (iOnlineGuests & " Guests ")
		If iOnlineAnon > 0 Then ezapiWhosOnline = ezapiWhosOnline & (iOnlineAnon & " Anonymous ")

'Construct profile links from name and id arrays
		If aOnlineNames Then
			If UBound(aOnlineNames) > 0 Then
				ezapiWhosOnline = ezapiWhosOnline & ("<p>")
				For aon = 0 to UBound(aOnlineNames) - 1
					ezapiWhosOnline = ezapiWhosOnline & ("- <a href=""http://" & sPub & ".ezboard.com/" & sBoardID & ".showUserPublicProfile?gid=" & aOnlineProfiles(aon) & """>" & aOnlineNames(aon) & "</a> ")
				Next
				ezapiWhosOnline = ezapiWhosOnline & (" - </p>")
			End If
		End If
	End If

End Function